Belirli Bir Metin İçeren Hücreleri Seçme

Belirli Bir Metin İçeren Hücreleri Seçme, istenen değerin içeren hücrelerin seçilmesini öğreten bir Hazır Makro Kodu yer almaktadır.

Hazır Kod: Belirli Bir Metin İçeren Hücreleri Seçme

Sub MetinIcerenHucresiSec()

    Dim sonSatir As Long
    Dim sonSutun As Long
    Dim i As Long, j As Long
    Dim kriter As String
    Dim secimAraligi As Range
   
    kriter = "Ali"
   
    sonSatir = Cells(Rows.Count, 1).End(xlUp).Row
    sonSutun = Cells(1, Columns.Count).End(xlToLeft).Column
   
    For i = 1 To sonSatir
        For j = 1 To sonSutun
            If InStr(1, Cells(i, j).Value, kriter, vbTextCompare) > 0 Then
                If secimAraligi Is Nothing Then
                    Set secimAraligi = Cells(i, j)
                Else
                    Set secimAraligi = Union(secimAraligi, Cells(i, j))
                End If
            End If
        Next j
    Next i
   
    If Not secimAraligi Is Nothing Then
        secimAraligi.Select
    Else
        MsgBox "Belirtilen metni içeren hücre bulunamadı."
    End If

End Sub

Açıklama

• InStr(1, Cells(i, j).Value, kriter, vbTextCompare) > 0: Bu satır, hücredeki değerin belirli bir metni içerip içermediğini kontrol eder. InStr fonksiyonu, hücredeki değerin içinde aranan metnin konumunu döndürür. Eğer metin bulunursa, pozitif bir sayı döner, yoksa sıfır döner.
• kriter = "Ali": Bu satır, aranan metni belirler. Bu örnekte, "Ali" kelimesi aranmaktadır.
• secimAraligi.Select: Bu satır, belirlenen metni içeren hücreleri seçer.

Kullanım

Bir modül ekleyin ve yukarıdaki kodu yapıştırın.

Üstteki gibi basit bir tablo oluşturun ve kodu çalıştırın.

Sonuç yukarıdaki gibi olacaktır.